[gpeters71]

.anc >>> .xpi file conversion.

Currently toolpaths created in AlphaCAM are given the .anc file extension; however, to send over the network to our NUM 1020, these have to be manually changed to .xpi files. The user then has to open the program to remove any header text and information from the new file before the CNC router will read the program.

I am looking for some kind of add -in and Post MOD that will automatically do the conversion and eliminate any unwanted information that the router does not need to eliminate any human error.

[Dan911]

When you output NC change the "Save file type" from .anc to "all files". Than add .xpi to the end of your file name. The unwanted header text can easily be modified/removed with a simple edit in your post processor.

[Maroslav4]

Better variant for save to correct extension (for a template post) is using vba add in Alternative file extension.

Add to post $7500 add to this sequence extension which you want XPI, ANC ....
Activate in addin Alternative file extension

Enjoy

[Dan911]

Better variant for save to correct extension (for a template post) is using vba add in Alternative file extension.

Add to post $7500 add to this sequence extension which you want XPI, ANC ....
Activate in addin Alternative file extension

Enjoy

This confirms the old analogy" knowing a little is worst than knowing nothing at all" (referring to my post)

Great tip Maroslav4

[Maroslav4]

This confirms the old analogy" knowing a little is worst than knowing nothing at all"

Hey boy, now i do not know how do you mean it.

[Dan911]

Hey boy, now i do not know how do you mean it.

LOL... Wasn't quick enough editing my post after I reread. Was referring to my post!

Great tip and I will definitely use.

Dan

[Maroslav4]

Sorry In a VBA post you can directly programming procedure which can rename your NC file (i can share this part of code if someone will need it). And the BEST advice (but it works only 2015 and more i think) is use NC output manager .


Hope that usefull

[gpeters71]

When you output NC change the "Save file type" from .anc to "all files". Than add .xpi to the end of your file name. The unwanted header text can easily be modified/removed with a simple edit in your post processor.

I guess my next question is WHAT do I edit in the post processor? The last thing I need is to F*** up the post. I have added the post processor text to help.

$----------------------------- HEADER ---------------------------------------


Customer : Auto-Sleepers
Machine : Duemas
Control : NUM 1020
Units : MM
No of Axis : XYZ
Coord System : Absolute
Z-Axis : Vertical
Contact : James MacLachlan
Post Author : Paul Green
Ver 1 Date : 21/07/2003
Notes : Machine has no Tool Changer and spindle in only 1 direction.
Last Edit : 16/03/04 - imj logig added for drilling


$------------------------- PROGRAM LEADING/TRAILING LINES -------------------
$10 File LEADING lines
$LET PROGNUM = "?"
%[PROGNUM] ([FNM])
$12 Main Program LEADING lines
N[N] G0 G90
N[N] Z130
$15 Main Program TRAILING lines
N[N] G0 Z130
N[N] G0 X[X_HOME] Y[Y_HOME]
N[N] M2
$17 File TRAILING Lines
$----------------------- RAPID MOVES ----------------------------------------
$20 Rapid Move in XY (MILL/ROUTER/FLAME/LASER) or XZ (LATHE) only
$IF TT=4 GOTO 99
''
N[N] G0 X[AX] Y[AY]
''
$LL99
$----------------------------------------------------------------------------
$21 3D Rapid Move in XYZ (MILL/ROUTER ONLY)
N[N] G0 X[AX] Y[AY] Z[AZ]
$----------------------------------------------------------------------------
$25 Rapid Move in Z only (MILL etc)
$IF FIRST_RAPID = 1
$LET FIRST_RAPID = 0
$ELSE
N[N] G0 Z[AZ]
$ENDIF
$----------------------------------------------------------------------------
$30 Lines BEFORE a rapid move if Z levels are not used eg Laser or Geometry
UP
$----------------------------------------------------------------------------
$35 Lines AFTER a rapid move if Z levels are not used eg Laser or Geometry
DN
$----------------------- MACHINING FEED MOVES -------------------------------
$40 Machining FEED lines
$IF MC + IN + OUT = 2
N[N] G1 [TC] D[T] X[AX] Y[AY] Z[AZ] F[F]
$ELSE
N[N] G1 X[AX] Y[AY] Z[AZ] F[F]
$ENDIF
$----------------------------------------------------------------------------
$50 Feed CW arc (AlphaCAM will automatically limit arcs to 120 degrees maximum)
$MODAL OFF X, Y
N[N] G2 X[AX] Y[AY] Z[AZ] R[R] F[F]
$MODAL ON
$----------------------------------------------------------------------------
$60 Feed CCW arc (AlphaCAM will automatically limit arcs to 120 degrees maximum)
$MODAL OFF X, Y
N[N] G3 X[AX] Y[AY] Z[AZ] R[R] F[F]
$MODAL ON
$------------------------ TOOL CHANGES --------------------------------------
$70 Cancel current tool. Use [T] for current tool number if required.
$IF NT = 0
N[N] M5
$ELSE
$ENDIF
''
$75 Code for CLOCKWISE spindle rotation - entered into variable ROT (or RT)
''
$76 Code for COUNTER-CLOCKWISE spindle rotation - entered into variable ROT
''
$80 Select new tool. Use [T] for new tool number, [S] for spindle speed.
$IF T = 1 ''LH DRILL
N[N] M101 ''SELECT LH DRILL
N[N] M18 ''START LH DRILL
$ELSEIF T = 2 ''RH DRILL
N[N] M102 ''SELECT LH DRILL
N[N] M23 ''START LH DRILL
$ELSE T => 3
N[N] M3 ''SPINDLE ON
N[N] M3 S[S]
N[N] G4 F10
$ENDIF
''
$LET FIRST_RAPID = 1
$----------------------------------------------------------------------------
CWP = Current Work Plane:
If CWP = 0 this means Conventional Milling (ie XY, GLOBAL coords)
If CWP = 1 it means XY, 2 = XZ, 3 = YZ, 4 = 3D and AX AY AZ are LOCAL coords


$88 Set Current Work Plane
$-------------------------- SUBROUTINES ------------------------------------
$90 CALL subroutine. Use [SN] for subroutine number.
N[N] G77 N[SN*BINC+SUB_ST] N[SN*BINC+SUB_ST+(BINC-1)]
$----------------------------------------------------------------------------
$100 BEGIN subroutine. Use [SN] for subroutine number.
$LET BNUM = 0
N[SN*BINC+SUB_ST] (SUBROUTINE START)
$LET BNUM = BNUM + NUMINC
N[SN*BINC+BNUM+SUB_ST] G0 X[AX] Y[AY]
$----------------------------------------------------------------------------
$110 END subroutine
N[SN*BINC+SUB_ST+(BINC-1)] (SUBROUTINE END)
$------------------- REFERENCE ZERO or ORIGIN SHIFT -------------------------
$120 Origin shift. Use [OX] and [OY] for values to shift by)
N[N] G59 X[OX] Y[OY]
$----------------------------------------------------------------------------
$130 Cancel Origin shift. [OX] and [OY] are values by which origin was shifted)
N[N] G59 X0 Y0
$----------------------- MACHINE TOOL COMPENSATION --------------------------
NOTE: Codes given in $140 to $142 are assigned to TC as required for each path
$140 Code to CANCEL Machine Tool Compensation
G40
$141 Code for LEFT Machine Tool Compensation
G41
$142 Code for RIGHT Machine Tool Compensation
G42
$145 Percentage increase in blend radius for sharp internal corners
1
$146 Adjust G41/42 code at internal corners for tool radius (1 = Yes 0 = No)
1
$147 Comp can be applied on Rapid Approach (1 = Yes 0 = No)
0
' $147=1 is only a flag to indicate that the code in $20 and $25 is correct if comp
' is asked for on the rapid approach. It does NOT force this to happen. For
' comp to be applied on rapid approach, the Apply Comp on Rapid Approach check
' box must be set to YES for each operation. If set, MC=1 in $20 & $25 and
' MC = 0 in $40, 50 and 60, so code for $40, 50 and 60 does not have to be changed
$----------------------- COOLANT OFF/MIST/FLOOD/TOOL CODES ------------------
Codes in $150 to $153 are assigned to CLT as required for each path
$150 Code to Turn Coolant OFF
''
$151 Code to apply MIST Coolant
''
$152 Code to apply FLOOD Coolant
''
$153 Code to apply THROUGH TOOL Coolant
''
$------------------------ DRILLING/TAPPING CYCLES ---------------------------
[ZR] = Retract level, the Z level to rapid down to before feed down begins.
[ZB] = Z value of the bottom of the hole, [ZP] = peck DISTANCE.
[ZS] = Safe Rapid level, [ZM] = Material top. All values are ABSOLUTE.


For LINEAR code use $210/211, $214/215 etc. For SUBROUTINES use $205/206 for
X/Y values and $212/216 etc to set Z levels etc before calling the subroutine.


$200 CANCEL drill/tapping cycle
$IF T = 1
N[N] M20
N[N] M100
$ELSEIF T = 2
N[N] M24
N[N] M100
$ELSE
$ENDIF
''
$----------------------------------------------------------------------------
$205 First Hole in SUBROUTINE. NOTE $205/206 apply to ALL drill/peck etc cycles
$206 Next holes in Subroutine
$----------------------------------------------------------------------------
DRILL cycle - traverse to next hole at SAFE RAPID level [ZS]
$210 First Hole
$IF T = 1
N[N] G0 X[AX] Y[AY]
N[N] M22
$ELSEIF T = 2
N[N] G0 X[AX] Y[AY]
N[N] M26
$ELSE
N[N] G0 Z[ZR]
N[N] G1 Z[ZB] F[F]
N[N] G0 Z[ZS]
$ENDIF
''
$211 Next holes
$IF T = 1
N[N] G0 X[AX] Y[AY]
N[N] M22
$ELSEIF T = 2
N[N] G0 X[AX] Y[AY]
N[N] M26
$ELSE
N[N] G0 X[AX] Y[AY]
N[N] G0 Z[ZR]
N[N] G1 Z[ZB] F[F]
N[N] G0 Z[ZS]
$ENDIF
''
$212 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
DRILL cycle - traverse to next hole at RETRACT level [ZR]
$214 First Hole
$IF T = 1
N[N] G0 X[AX] Y[AY]
N[N] M22
$ELSEIF T = 2
N[N] G0 X[AX] Y[AY]
N[N] M26
$ELSE
N[N] G0 Z[ZR]
N[N] G1 Z[ZB] F[F]
N[N] G0 Z[ZR]
$ENDIF
''
$215 Next holes
$IF T = 1
N[N] G0 X[AX] Y[AY]
N[N] M22
$ELSEIF T = 2
N[N] G0 X[AX] Y[AY]
N[N] M26
$ELSE
N[N] G0 X[AX] Y[AY]
N[N] G1 Z[ZB] F[F]
N[N] G0 Z[ZR]
$ENDIF
''
$216 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
PECKING cycle - traverse to next hole at SAFE RAPID level [ZS]
$220 First hole
$MSG PECK CYCLE NOT ALLOWED - POST WILL EXIT - MODIFY PROGRAM
$EXIT
''
$221 Next holes
''
$222 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
PECKING cycle - traverse to next hole at RETRACT level [ZR]
$224 First hole
$MSG PECK CYCLE NOT ALLOWED - POST WILL EXIT - MODIFY PROGRAM
$EXIT
''
$225 Next holes
''
$226 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
TAPPING cycle - traverse to next hole at SAFE RAPID level [ZS]
$230 First hole
$231 Next holes
$232 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
TAPPING cycle - traverse to next hole at RETRACT level [ZR]
$234 First hole
$235 Next holes
$236 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
BORING/REAMING/SPOT FACE etc - traverse to next hole at SAFE RAPID level [ZS]
$240 First Hole
$241 Next holes
$242 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$----------------------------------------------------------------------------
BORING/REAMING/SPOT FACE etc - traverse to next hole at RETRACT level [ZR]
$244 First Hole
$245 Next holes
$246 Set PARAMETERS before Subroutine call (AlphaCAM will insert Subroutine call)
$-------------------------- GENERAL FORMATS ---------------------------------
Separate modal values with spaces. More than one letter is OK eg X VX VY
$500 Modal Text (Will not be repeated in following lines)
G0 G1 G2 G3
$502 Modal ABSOLUTE Values (Will not be repeated if the VALUE is the same)
X Y Z F
$504 Modal INCREMENTAL Values (Will not be put into NC code if VALUE is ZERO)
I J
$510 X Y Z I J K values must have + as well as - signs (1 = Yes, 0 = no)
0
$515 Use point <.> as decimal separator (1 = Yes, 0 = use comma <,>)
1
$520 Put sub-routines at end of main program (1 = Yes, 0 = put at start)
1
$525 Quadrant Limit arcs (1 = Yes, 0 = Standard AlphaCAM 180 degree limit)
0
$526 Output arcs as one move (1 = Yes, 0 = No - split arcs >= 180)
0
$527 Output HELICAL (XYZ) arcs as straight line segments (1 = Yes, 0 = No)
0
' 530 Determines which PLANAR arcs are output as straight line segments.
$530 0=None, 1=All, 2=All Except Horizontal (XY), 3=Except Horizontal and Vertical (YZ or XZ)
3
$531 Maximum Arc Radius - arcs will be output as straight lines if radius >
0
$532 If arcs are straight line segments, give chord error (mm or inches)
.05
$540 Suppress Operations List, START and Comments in NC code (1 = Yes, 0 = No)
0
$-------------------------- NUMBER FORMATS ----------------------------------
$700 SUBROUTINE Number format
6
$701 Leading figures
0
$702 Figures after point
0
$705 Subroutine start number
1
$----------------------------------------------------------------------------
$710 LINE NUMBER format
6
$711 Leading figures
0
$712 Figures after point
0
$715 Line start number
5
$716 Line number increment
5
$----------------------------------------------------------------------------
$720 X Y Z values format
3
$721 Leading figures
0
$722 Figures after point
3
$----------------------------------------------------------------------------
$730 ARC centre/radius format
3
$731 Leading figures
0
$732 Figures after point
3
$----------------------------------------------------------------------------
$740 SPINDLE SPEED format
6
$741 Leading figures
0
$742 Figures after point
0
$743 Maximum Spindle Speed
22000
$744 Fixed Speeds (eg 100, 200, 1000, 2000 ... 0 = speed is variable)
0
$NOTE: Fixed speeds can use more than one line. 80 chars per line maximum
AlphaCAM will select the nearest lower value to the calculated value.
$745 below only applies if $744 is 0 - ie variable speed range.
$745 Round Speed Up/Down to Nearest: (.1 or 1 or 10 ... 0 = don't round)
10
$----------------------------------------------------------------------------
$750 MACHINING FEED format
6
$751 Leading figures
0
$752 Figures after point
0
$753 Maximum Feed Rate (Use mm/min or in/min as appropriate for this Post)
40000 mm/min
$755 Round Feed Up/Down to Nearest: (.1 or 1 or 10 ... 0 = don't round)
10
$----------------------------------------------------------------------------
$760 TOOL NUMBER format
6
$761 Leading figures
0
$762 Figures after point
0
$------------------------ RAPIDS and TOOL CHANGE TIMES ----------------------
Use mm/min or in/min as appropriate for this Post.
$900 XY Rapid Speed
30000 mm/min
$901 Z Rapid Speed
7000 mm/min
$902 Time to change tool (seconds)
0
$--------------------------- USER VARIABLES ---------------------------------
ALL user variables must be declared. Variable names can be up to 20 chars.
Prompts can be up to 50 chars max and can include a default inside < >.
Put (" ") as format for a text variable. Put ( ) as the format of any numeric
variable which is to have the same format as X Y (Z) moves. If a different
format is required, put (Format, Lead figs, Trail figs) eg (6,0,0) = Integer.


$1000 VARIABLE (format) "Prompt <default>"
PROGNUM ("4") "Enter Program Number <1234>"
FIRST_RAPID ( )
X_HOME ( ) "Enter X-Axis Home Position <0>"
Y_HOME ( ) "Enter Y-Axis Home Position <0>"
PECK ( )
CLEAR_DEPTH ( ) = 2
$ --------------------------- End of Post -----------------------------------

[Maroslav4]

Hello,

try this.
$540 Suppress Operations List, START and Comments in NC code (1 = Yes, 0 = No)
1 (Change from 0)

Marek

[steryd]

it is not in there You have to check in machine definition files.
changing $540 will only change if there will or won't be comment in front of operations.

[Maroslav4]

it is not in there You have to check in machine definition files.
changing $540 will only change if there will or won't be comment in front of operations.

Yes, but if he does not use "output to portadisk" in a Alphaedit. He have to delete this manually, these information are generate by Alphacam automatically and every drive control which i see cannot read it. It is not generate some info about operation. but also many information in a start of program. It looks like this. After generate this is code prepare for sending to machine over Alphaedit, where we can set which information we want send it to drive control. This is Output on portadisk.

Second thing can be some wrong syntax in a code and it it second thing.


Operation List POST: Fanuc 6mb (R arcs - mm)
--------------------------------------------------
OP 1 DRILL HOLES TOOL 8 DRILL_T08_VERTIKAL FI 8
TOOL DIAMETER 8, HOLE DIAMETERS 10
Feed Distance: 336 Time for OP 1: 2m 02s
OP 2 DRILL HOLES TOOL 11 T41_11_FREZA DIA FI 10
TOOL DIAMETER 10, HOLE DIAMETERS 10
Feed Distance: 336 Time for OP 2: 2m 22s
--------------------------------------------------
Total Feed Distance .......................... 672
Tool Change Time .......................... 0m 20s
Total Time ................................ 4m 45s
--------------------------------------------------
Material: HLINÍK
Protect sharp corners before stacking
--------------------------------------------------
START
~(VRTANIE)
%
:0000
N10 (PROGRAM PRODUCED - 28 MAR 16)
N20 G90 G71
N30 G40 G80
~(OP 1 DRILL HOLES TOOL 8 DRILL_T08_VERTIKAL FI 8)
~(TOOL DIAMETER 8, HOLE DIAMETERS 10)
N40 T0808 M03 'Select tool and offset
N50 S4000 H08 M06 'Next tool is 11, Next XY is 275., 827.5
N60 G0 Z10.
N70 X275. Y827.5
N80 G98 G81 X275. Y827.5 Z-18. R10. F800 M09
N90 X275. Y777.5
N100 X275. Y527.5
N110 X275. Y477.5
N120 X275. Y77.5
N130 X275. Y27.5
N140 X775. Y27.5
N150 X775. Y77.5
N160 X775. Y477.5
N170 X775. Y527.5
N180 X775. Y777.5
N190 X775. Y827.5
N200 M09
N210 G80
N220 T0
~(OP 2 DRILL HOLES TOOL 11 T41_11_FREZA DIA FI 10)
~(TOOL DIAMETER 10, HOLE DIAMETERS 10)
N230 T1111 M03 'Select tool and offset
N240 S4000 H11 M06 'Next tool is 00, Next XY is 275., 827.5
N250 G0 Z10.
N260 X275. Y827.5
N270 G98 G81 X275. Y827.5 Z-18. R10. F800 M09
N280 X275. Y777.5
N290 X275. Y527.5
N300 X275. Y477.5
N310 X275. Y77.5
N320 X275. Y27.5
N330 X775. Y27.5
N340 X775. Y77.5
N350 X775. Y477.5
N360 X775. Y527.5
N370 X775. Y777.5
N380 X775. Y827.5
N390 M09
N400 G80
N410 T0
N420 M30
%


That im right??

PS: sorry my english is not perfect

[gpeters71]

Marek,

You are a ROCKSTAR! Thank you for the support. This worked!!

[Tomax]

Better variant for save to correct extension (for a template post) is using vba add in Alternative file extension.

Add to post $7500 add to this sequence extension which you want XPI, ANC ....
Activate in addin Alternative file extension

Enjoy

I'm a bit confused about this ... Did you mean adding $7500 inside post(mypost.arp)? How would correct syntax look like if I want output file with .nc extension?
Thank you!

[scevero]

Try this on your mypost.arp:

$7500
xpi,anc,nc

i placed this 2 lines just above these ones from my mach3 post:

$ ------------------------- ends $1208 user defined cycle


$ ---------------------- End of Post

if you only want .xpi extension then erase the other ones and leave your extension alone. Regards