I was looking for a post for alphacam to Biesse rover 220.
Or a contact for someone who can write one for me thanks in advance.
Also one for an Esprit Lightning 100 hd
I was looking for a post for alphacam to Biesse rover 220.
Or a contact for someone who can write one for me thanks in advance.
Also one for an Esprit Lightning 100 hd
try this & let me know
post:
$----------------------------- HEADER ---------------------------------------
Machine : Biesse Rover 20
Units : MM
Axes Used : XYZ
Coord System : Absolute
Z-Axis : Vertical
Contact :
Tel :
Post Author : Licom
Date : 01/07/99
: Post processor can handle sloping lead ins and engraving
: Use tool Numbers as below to activate required tools
: T1 = Head 1 Routing
: T2 = Sawing unit X direction only
: all drilling is handled with multidrilling
: Output via COMMS | Output to Portadisk to A:\P_p\Prog with no file extension
$----------------------------------------------------------------------------
Notes and remarks that are to appear in the NC code (but NOT be sent to the machine)
should be preceded by ' (a single apostrophe)
Notes and remarks that are local to the Post for your information only should be
preceded by '' (TWO single apostrophes)
$------------------------- PROGRAM LEADING/TRAILING LINES -------------------
$5 $STORE, $RUN and $RECALL - See manual Appendix A for details
$10 File LEADING lines
START
$12 Main Program LEADING lines
$LET LEFT = "["
$LET RIGHT = "]"
''
[LEFT]COMMENTO[RIGHT]
[FNM]
[LEFT]PARAMETRI01[RIGHT]
N[N] G71 HC=1 LX=[PANEL_X] LY=[PANEL_Y] LZ=[PANEL_Z] FIL=0 BLO=0 ACC=0 RUO=0 PRS=1 PRL=1 KA=0.000
%
[LEFT]UTENSILI01[RIGHT]
%
[LEFT]CONTORNATURA01[RIGHT]
N[N] XO[XOFFSET] YO[YOFFSET] G0
$15 Main Program TRAILING lines
%
$17 File TRAILING Lines
$----------------------- RAPID MOVES ----------------------------------------
$20 Rapid Move in XY (MILL/ROUTER/FLAME/LASER) or XZ (LATHE) only
$LET FIRST_ENGRAVE = 1
$LET FIRST_ROUTER = 1
$----------------------------------------------------------------------------
$21 3D Rapid Move in XYZ (MILL/ROUTER ONLY)
$----------------------------------------------------------------------------
$25 Rapid Move in Z only (MILL etc)
$if pat(1) > 0 goto 99 '' multidrilling so exit section
''
''Set XY for saw Z is set for a sloping lead in
''
$LET MY_X = CX
$LET MY_Y = CY
$LET MY_Z = AZ
''
$IF T = 2 GOTO 99 ''Saw in X direction
$IF TT = 4 GOTO 99 ''Drills
$IF LRB = 1 GOTO 99 ''If rapid move is Last Rapid Before cutting path
$IF FRA = 1 ''If rapid move is First Rapid After cutting path
N[N] G0 L=PSU ''Line to move to next position but keep router running
$ENDIF
$LL99
$----------------------------------------------------------------------------
$30 Lines BEFORE a rapid move if Z levels are not used eg Laser or Geometry
$----------------------------------------------------------------------------
$35 Lines AFTER a rapid move if Z levels are not used eg Laser or Geometry
$----------------------- MACHINING FEED MOVES -------------------------------
$40 Machining FEED lines
''
$IF MOT = 10
$GOTO 1000
$ELSEIF T = 2
$GOTO 2000
$ELSEIF T = 1
$GOTO 3000
$ENDIF
''
''Engrave
''
$LL1000
$IF FIRST_ENGRAVE = 1
$LET FIRST_ENGRAVE = 2
$ELSEIF FIRST_ENGRAVE = 2
$MODAL OFF X Y Z
N[N] X[CX] Y[-CY] Z=PRK TP=1 PRF=[-AZ] F=[F/1000] VF=[F/1000] S=[S] [TC] L=PON M55 G28
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$LET FIRST_ENGRAVE = 3
$ELSEIF FIRST_ENGRAVE = 3
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ENDIF
$GOTO 9999
''
''Sawing X direction only
''
$LL2000
$IF FF = 1
N[N] XIN=[MY_X] XF=[AX] QY=[-MY_Y] PRF=[-CZ] VT=[F/1000] VF=[F/1000] USC=0 ZZ2=0 RES=1 L=G9
$ELSEIF FF <> 1
$ENDIF
$GOTO 9999
''
''Standard routing
''
$LL3000
$IF FIRST_ROUTER = 1
$GOTO 100
$ELSEIF FIRST_ROUTER = 2
$GOTO 200
$ELSEIF FIRST_ROUTER = 3
$GOTO 300
$ENDIF
''
$LL100
$IF ABS(IX) + ABS(IY) = 0
$GOTO 10
$ELSE
$GOTO 20
$ENDIF
''
$LL10
''First feed move standard lead in, Note uses CXCY because $20 is not used, AZ is required on this first line of code
$LET FIRST_ROUTER = 2
$LET LEAD_IN = 1
$LET X_START = CX
$LET Y_START = CY
$LET Z_START = AZ
$GOTO 9999
''
$LL20
''First feed move sloping lead in, First position and first feed line must be output here
$MODAL OFF X Y Z
N[N] X[CX] Y[-CY] Z=PRK TP=1 PRF=[-MY_Z] F=[F/1000] VF=[F/1000] S=[S] [TC] L=PON M55 G28
$IF MC + IN = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ELSEIF MC + OUT = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1 [TC]
$ELSE
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ENDIF
$LET FIRST_ROUTER = 2
$LET LEAD_IN = 2
$GOTO 9999
''Standard second and any move thereafter for both normal & sloping lead ins
$LL200
$IF LEAD_IN = 1
$GOTO 30
$ELSEIF LEAD_IN = 2
$GOTO 40
$ENDIF
''Standard second move for normal lead ins
$LL30
$MODAL OFF X Y Z
N[N] X[X_START] Y[-Y_START] Z=PRK TP=1 PRF=[-Z_START] F=[F/1000] VF=[F/1000] S=[S] [TC] L=PON M55 G28
$IF MC + IN = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ELSEIF MC + OUT = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1 [TC]
$ELSE
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ENDIF
$LET FIRST_ROUTER = 3
$GOTO 9999
''Standard second move for sloping lead ins
$LL40
$IF MC + IN = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ELSEIF MC + OUT = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1 [TC]
$ELSE
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ENDIF
$LET FIRST_ROUTER = 3
$GOTO 9999
''
''Standard THIRD and any move thereafter for both normal & sloping lead ins
$LL300
$IF MC + IN = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ELSEIF MC + OUT = 2
N[N] X[AX] Y[-AY] ZI[-IZ] G1 [TC]
$ELSE
N[N] X[AX] Y[-AY] ZI[-IZ] G1
$ENDIF
$GOTO 9999
''
$LL9999
$----------------------------------------------------------------------------
$50 Feed CW arc (APS will automatically limit arcs to 180 degrees maximum)
''
$IF FF = 1
N[N] X[MY_X] Y[-MY_Y] Z=PRK TP=1 PRF=[-CZ] F=[F/1000] VF=[F/1000] S=[S] [TC] L=PON M55 G28
$ENDIF
$MODAL OFF
$IF MC + IN = 2
N[N] X[AX] Y[-AY] R-[R] G5
$ELSEIF MC + LF = 2
N[N] X[AX] Y[-AY] R-[R] G5 [TC]
$ELSE
N[N] X[AX] Y[-AY] R-[R] G5
$ENDIF
''
$LL99
$LET FIRST_ROUTER = 3
$----------------------------------------------------------------------------
$60 Feed CCW arc
''
$IF FF = 1
N[N] X[MY_X] Y[-MY_Y] Z=PRK TP=1 PRF=[-CZ] F=[F/1000] VF=[F/1000] S=[S] [TC] L=PON M55 G28
$ENDIF
$MODAL OFF
$IF MC + IN = 2
N[N] X[AX] Y[-AY] R[R] G4
$ELSEIF MC + LF = 2
N[N] X[AX] Y[-AY] R[R] G4 [TC]
$ELSE
N[N] X[AX] Y[-AY] R[R] G4
$ENDIF
''
$LL99
$LET FIRST_ROUTER = 3
$------------------------ TOOL CHANGES --------------------------------------
$70 Cancel current tool. Use [T] for current tool number if required.
$if pat(1) > 0 goto 99 '' multidrilling so exit section
$IF T = 1
N[N] G0 L=POFF ''Head up spindle off
$ELSEIF T = 2
$ELSEIF T < 20
$ELSE
$ENDIF
''
$ll99
$75 Code for CLOCKWISE spindle rotation - entered into variable ROT (or RT)
M03
$76 Code for COUNTER-CLOCKWISE spindle rotation - entered into variable ROT
M04
$80 Select new tool. Use [T] for new tool number, [S] for spindle speed.
$if pat(1) > 0 goto 99 '' multidrilling so exit section
$IF T = 1
N[N] PAN=1 ST1="[TNM]" L=PCUA
$ELSEIF T = 2
$ELSEIF T < 20
$ELSE
$ENDIF
$ll99
$-------------------------- SUBROUTINES ------------------------------------
$90 CALL subroutine. Use [SN] for subroutine number.
$msg
Alarm subroutines not configured for Biesse machine
Contact Licom systems if required
$
$----------------------------------------------------------------------------
$100 BEGIN subroutine. Use [SN] for subroutine number.
$----------------------------------------------------------------------------
$110 END subroutine
$------------------- REFERENCE ZERO or ORIGIN SHIFT -------------------------
$120 Origin shift. Use [OX] and [OY] for values to shift by)
$----------------------------------------------------------------------------
$130 Cancel Origin shift. [OX] and [OY] are values by which origin was shifted)
$----------------------- MACHINE TOOL COMPENSATION --------------------------
NOTE: Codes given in $140 to $142 are assigned to TC as required for each path
$140 Code to CANCEL Machine Tool Compensation
G40
$141 Code for LEFT Machine Tool Compensation
G42
$142 Code for RIGHT Machine Tool Compensation
G41
$145 Percentage increase in blend radius for sharp internal corners
0
$146 Adjust G41/42 code at internal corners for tool radius (1 = Yes 0 = No)
1
$----------------------- COOLANT OFF/MIST/FLOOD/TOOL CODES ------------------
Codes in $150 to $153 are assigned to CLT as required for each path
$150 Code to Turn Coolant OFF
M09
$151 Code to apply MIST Coolant
M07
$152 Code to apply FLOOD Coolant
M08
$153 Code to apply THROUGH TOOL Coolant
M10
$------------------------ DRILLING/TAPPING CYCLES ---------------------------
[ZR] = Retract level, the Z level to rapid down to before feed down begins.
[ZB] = Z value of the bottom of the hole, [ZP] = peck DISTANCE.
[ZS] = Safe Rapid level, [ZM] = Material top. All values are ABSOLUTE.
For LINEAR code use $210/211, $214/215 etc. For SUBROUTINES use $205/206 for
X/Y values and $212/216 etc to set Z levels etc before calling the subroutine.
$200 CANCEL drill/tapping cycle
$----------------------------------------------------------------------------
$205 First Hole in SUBROUTINE. NOTE $205/206 apply to ALL drill/peck etc cycles
N[N] X[AX] Y[-AY]
$206 Next holes in Subroutine
N[N] X[AX] Y[-AY]
$----------------------------------------------------------------------------
DRILL cycle - traverse to next hole at SAFE RAPID level [ZS]
$210 First Hole
$if pat(1) <> 1 goto 99 '' not a master drill so exit section
$if wvf = 0
N[N] X[AX] Y[-AY] T[T][pat(2)] VF=[F] PRF=[-ZB] L=G97
$elseif wvf = 1
$goto 10
$elseif wvf = 2
$goto 20
$elseif wvf = 3
$goto 30
$elseif wvf = 4
$goto 40
$endif
$goto 99
''
$ll10
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH6 VF=[F/1000] PRF=[-ZB] L=G4
$goto 99
''
$ll20
$if T = 11
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH1 VF=[F/1000] PRF=[-ZB] L=G1
$elseif T = 13
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH3 VF=[F/1000] PRF=[-ZB] L=G1
$endif
$goto 99
''
$ll30
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH5 VF=[F/1000] PRF=[-ZB] L=G2
$goto 99
''
$ll40
$if T = 12
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH2 VF=[F/1000] PRF=[-ZB] L=G3
$elseif T = 14
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH4 VF=[F/1000] PRF=[-ZB] L=G3
$endif
$goto 99
''
$ll99
$211 Next holes
$212 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
DRILL cycle - traverse to next hole at RETRACT level [ZR]
$214 First Hole
$if pat(1) <> 1 goto 99 '' not a master drill so exit section
$if wvf = 0
N[N] X[AX] Y[-AY] T[T][pat(2)] VF=[F] PRF=[-ZB] L=G97
$elseif wvf = 1
$goto 10
$elseif wvf = 2
$goto 20
$elseif wvf = 3
$goto 30
$elseif wvf = 4
$goto 40
$endif
$goto 99
''
$ll10
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH6 VF=[F/1000] PRF=[-ZB] L=G4
$goto 99
''
$ll20
$if T = 11
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH1 VF=[F/1000] PRF=[-ZB] L=G1
$elseif T = 13
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH3 VF=[F/1000] PRF=[-ZB] L=G1
$endif
$goto 99
''
$ll30
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH5 VF=[F/1000] PRF=[-ZB] L=G2
$goto 99
''
$ll40
$if T = 12
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH2 VF=[F/1000] PRF=[-ZB] L=G3
$elseif T = 14
N[N] QX=[AX] QY=[-AY] QZ=[AZ] QQN=2 TH4 VF=[F/1000] PRF=[-ZB] L=G3
$endif
$goto 99
''
$ll99
$215 Next holes
$216 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
PECKING cycle - traverse to next hole at SAFE RAPID level [ZS]
$220 First hole
$221 Next holes
$222 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
PECKING cycle - traverse to next hole at RETRACT level [ZR]
$224 First hole
$225 Next holes
$226 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
TAPPING cycle - traverse to next hole at SAFE RAPID level [ZS]
$230 First hole
$231 Next holes
$232 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
TAPPING cycle - traverse to next hole at RETRACT level [ZR]
$234 First hole
$235 Next holes
$236 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
BORING/REAMING/SPOT FACE etc - traverse to next hole at SAFE RAPID level [ZS]
$240 First Hole
$241 Next holes
$242 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$----------------------------------------------------------------------------
BORING/REAMING/SPOT FACE etc - traverse to next hole at RETRACT level [ZS]
$244 First Hole
$245 Next holes
$246 Set PARAMETERS before Subroutine call (APS will insert Subroutine call)
$-------------------------- GENERAL FORMATS ---------------------------------
Separate modal values with spaces. More than one letter is OK eg X VX VY
$500 Modal Text (Will not be repeated in following lines)
$502 Modal ABSOLUTE Values (Will not be repeated if the VALUE is the same)
X Y Z F
$504 Modal INCREMENTAL Values (Will not be put into NC code if VALUE is ZERO)
I J ZI
$510 X Y Z I J K values must have + as well as - signs (1 = Yes, 0 = no)
0
$515 Use point <.> as decimal separator (1 = Yes, 0 = use comma <,>)
1
$520 Put sub-routines at end of main program (1 = Yes, 0 = put at start)
1
$525 Quadrant Limit arcs (1 = Yes, 0 = Standard APS 180 degree limit)
1
$526 Output arcs as one move (1 = Yes, 0 = No - split arcs >= 180)
0
$530 Output arcs as straight line segments (1 = Yes, 0 = No)
0
$531 Maximum Arc Radius - arcs will be output as straight lines if radius >
0
$532 If arcs are straight line segments, give chord error (mm or inches)
.1
$540 Suppress Operations List, START and Comments in NC code (1 = Yes, 0 = No)
1
'Set $560 - $580 all to 0 if machine is 3-axis.
$560 4/5 axis Programming point: (1 = pivot, 0 = tool tip)
0
$562 4/5 axis Tool C/L offset from pivot point in X
0
$563 4/5 axis Tool C/L offset from pivot point in Y
0
$565 4/5 axis Tool holder length
0
$570 4/5 axis Max angle (degrees). Set to 0 to indicate 3 - axis machine.
0
$580 Is this a horizontal machining centre (1 = Yes, 0 = No)
1
$582 Horizontal M/C. Select Work Plane BEFORE Tool Change (1 = yes, 0 = no)
0
$-------------------------- NUMBER FORMATS ----------------------------------
$700 SUBROUTINE Number format
6
$701 Leading figures
0
$702 Figures after point
0
$705 Subroutine start number
10
$----------------------------------------------------------------------------
$710 LINE NUMBER format
6
$711 Leading figures
0
$712 Figures after point
0
$715 Line start number
10
$716 Line number increment
10
$----------------------------------------------------------------------------
$720 X Y Z values format
1
$721 Leading figures
0
$722 Figures after point
2
$----------------------------------------------------------------------------
$730 ARC centre/radius format
1
$731 Leading figures
0
$732 Figures after point
2
$----------------------------------------------------------------------------
$740 SPINDLE SPEED format
1
$741 Leading figures
0
$742 Figures after point
0
$743 Maximum Spindle Speed
24000
$744 Fixed Speeds (eg 100, 200, 1000, 2000 ... 0 = speed is variable)
0
$NOTE: Fixed speeds can use more than one line. 80 chars per line maximum
APS will select the nearest lower value to the calculated value.
$745 below only applies if $744 is 0 - ie variable speed range.
$745 Round Speed Up/Down to Nearest: (.1 or 1 or 10 ... 0 = don't round)
100
$----------------------------------------------------------------------------
$750 MACHINING FEED format
6
$751 Leading figures
0
$752 Figures after point
0
$753 Maximum Feed Rate (Use mm/min or in/min as appropriate for this Post)
10000 mm/min
$755 Round Feed Up/Down to Nearest: (.1 or 1 or 10 ... 0 = don't round)
10
$----------------------------------------------------------------------------
$760 TOOL NUMBER format
6
$761 Leading figures
0
$762 Figures after point
0
$------------------------ RAPIDS and TOOL CHANGE TIMES ----------------------
Use mm/min or in/min as appropriate for this Post.
$900 XY Rapid Speed
75000 mm/min
$901 Z Rapid Speed
1500 mm/min
$902 Time to change tool (seconds)
10
$--------------------------- USER VARIABLES ---------------------------------
ALL user variables must be declared. Variable names can be up to 20 chars.
Prompts can be up to 50 chars max and can include a default inside < >.
Put (" ") as format for a text variable. Put ( ) as the format of any numeric
variable which is to have the same format as X Y (Z) moves. If a different
format is required, put (Format, Lead figs, Trail figs) eg (6,0,0) = Integer.
$1000 VARIABLE (format) "Prompt <default>" '' Remark for your info.
LEFT (" ")
RIGHT (" ")
XOFFSET (6,0,0) "X offset amount <5>"
YOFFSET (6,0,0) "Y offset amount <5>"
PANEL_X (1,0,2) "Enter The Panel Size In X <800>"
PANEL_Y (1,0,2) "Enter The Panel Size In Y <500>"
PANEL_Z (1,0,2) "Enter The Panel Thickness <18>"
MY_X (1,0,2)
MY_Y (1,0,2)
MY_Z (1,0,2)
FIRST_ENGRAVE (6,0,0)
FIRST_ROUTER (6,0,0)
X_START (1,0,2)
Y_START (1,0,2)
Z_START (1,0,2)
LEAD_IN (6,0,0)
HEIGHT_HOLES (1,0,2) "Height of cross drilled holes.<9>"
$-------------------------- USER PRE-DEFINED CODE -------------------------------
This section applies only to TOOLPATHS (not geometries). Any $number in the
range $1100 - $1149 can be used for each definition. First line after $number
appears in the first dialog box. Next lines up to $ line are variables with
prompts (which must be declared in $1000) which are to appear in second dialog
box. Lines up to next $ line will be added or inserted on any toolpath.
$-------------------------- USER DEFINED CYCLES -------------------------------
This section applies only to GEOMETRIES (not toolpaths). Use for machine or
work specific NC code (eg canned cycles) which require geometry coordinates.
Any $number in the range $1200 - $1249 can be used for each definition. First
line after $number appears in the first dialog box. Next lines up to first $
are variables with prompts (which must be declared in $1000) which are to
appear in second dialog box. Lines up to next $ line will be added at the end
of NC program so far created.
$1200
$ ------------------------- NC lines to be entered into program follow
$-------------------------- PATH ATTRIBUTES -------------------------------
Convert Attributes used in the API to PAT()
For example
1 = LICOMUKDMB1
means PAT(1) has the value of path.Attribute("LICOMUKDMB1")
$3000
1 = LicomUKDWMultiDrillMasterSlave
2 = LicomUKMPAMultiDrillBiesseSlaveNumbers
$ ---------------------- End of Post
don't surpose you have one for record 130 and zilog plus do you