[nigel2000]

hi
i am machining a part on a 5 axis, using rotary programming, first of all, i check the OD to see it is true by rotating the table

I probe the O/D to check the run-out of the part with 8 points, i have given each of these points a Q parameter

is there a function in Heidenhain which will find the biggest number of all these points?

[Uhrenholt]

hi
i am machining a part on a 5 axis, using rotary programming, first of all, i check the OD to see it is true by rotating the table

I probe the O/D to check the run-out of the part with 8 points, i have given each of these points a Q parameter

is there a function in Heidenhain which will find the biggest number of all these points?

Hi there.

When I do probing in my measuring/compare programs to check fixture/part alignment. Then I use Two datum’s in the table, one that holds the datum for the part, and another one to do the probing in.

When you do this, you can read the values from each datum, and compare measuring data. Part datum is fixed, then using cycle 413 you probe the new part and save the results in the measuring datum, now you got plenty of data to calculate what you want:-)

Use sysread to read the values from the control for your calculations:-)

No standard stuff for this that I know off.

Cheers

[Jukka Honkanen]

You can make a program comparing the values.
Here this measures the Z-value on different X/Y positions.

Here is an example.

Actual measuring program
0 BEGIN PGM Mittaa MM
1 M31
2 TOOL CALL "PROBE" Z
3 FN 0: Q0 =+0 ;rivinumerolaskuri
4 FN 0: Q3 =+9999 ; Min
5 FN 0: Q4 =-9999 ; Max
6 FN 26: TABOPEN Tulos.tab
7 LBL 1
8 FN 28: TABREAD Q1 =Q0 /"X"
9 FN 9: IF +Q1 EQU +999 GOTO LBL "end"
10 FN 28: TABREAD Q2 =Q0 /"Y"
11 TCH PROBE 427 MEASURE COORDINATE ~
Q263=+Q1 ;1ST POINT 1ST AXIS ~
Q264=+Q2 ;1ST POINT 2ND AXIS ~
Q261=+0 ;MEASURING HEIGHT ~
Q320=+5 ;SET-UP CLEARANCE ~
Q272=+3 ;MEASURING AXIS ~
Q267=-1 ;TRAVERSE DIRECTION ~
Q260=+25 ;CLEARANCE HEIGHT ~
Q281=+0 ;MEASURING LOG ~
Q288=+0 ;MAXIMUM LIMIT ~
Q289=+0 ;MINIMUM LIMIT ~
Q309=+0 ;PGM STOP TOLERANCE ~
Q330=+0 ;TOOL
12 FN 27: TABWRITE Q0 /"Z" = Q160
13 CALL PGM minmax
14 Q0 = Q0 + 1
15 FN 9: IF +1 EQU +1 GOTO LBL 1
16 LBL "end"
17 END PGM Mittaa MM


The "minmax" comparing

0 BEGIN PGM minmax MM
1 FN 11: IF +Q160 GT +Q3 GOTO LBL "ohi1"
2 FN 0: Q3 =+Q160
3 FN 27: TABWRITE 0 /"MIN" = Q160
4 LBL "ohi1"
5 FN 12: IF +Q160 LT +Q4 GOTO LBL "ohi2"
6 FN 0: Q4 =+Q160
7 FN 27: TABWRITE 0 /"MAX" = Q160
8 LBL "ohi2"
9 END PGM minmax MM


And the table. You can add writing the min and max values at the end of the main program.

17 END PGM Mittaa MM
NR X Y Z MIN MAX
0 100 50 -0.123 0.213
1 200 50
2 300 50
3 400 50
4 500 50
5 500 100
6 400 100
7 300 100
8 200 100
9 100 100
10 999
11
12
13
14
15
16
17
18
19
[END]